Reckon Accounts Premier Update to 2017 - Port problems AGAIN

  • 3
  • Question
  • Updated 1 month ago
Time to do the annual upgrade to the latest version of Reckon accounts but every year I go through the same problem over and over again. For some reason you need to go in and change all of the port settings to get the latest version to work and I simply can't remember how to do it because it is the 12 months since it was last done. A search on the website on port settings and upgrading from 2016 to 2017 does not bring any results. I don't want to spend 2 days again doing what should be a simple update to the software, instead it ends up as a complete computer reconfiguration every time
Photo of michael.coates

michael.coates

  • 144 Points 100 badge 2x thumb

Posted 2 years ago

  • 3
Photo of Phil Dodds

Phil Dodds

  • 150 Points 100 badge 2x thumb
I agree, we had to pay to have our IT guy come out to fix ours and he was very pleased as he had done a lot of them for others as well. A great money spinner for him
Photo of michael.coates

michael.coates

  • 144 Points 100 badge 2x thumb
Thanks for the reply, but what about people who don't have an "IT Guy" ......  we go through the same thing every year and it wastes days !  It should be a part of the upgrade sequence/procedure imo.

I haven't tried it yet but it will probably "update the database" which means we have no chance but to commit and continue with the upgrade to we get it working again and have no way of going back to 2016. These people really need to get smarter when they are writing to software, the end-users don't need to be software/firewall experts in my opinion !
(Edited)
Photo of Warren Aitken

Warren Aitken

  • 170 Points 100 badge 2x thumb
Thank you Michael & Phil. I had put off upgrading to 2017 as my previous experiences had not been pleasant ones. We use Reckon exclusively in a Grocery store and cannot afford to have the shop down for any period of time. I will be watching this space with interest........
Photo of Rav

Rav, Community Manager

  • 64,810 Points 50k badge 2x thumb
Hi Michael,

There is info on configuring exceptions on your firewall/anti-virus for the required ports for Reckon Accounts Business here -

Configuring my firewall/antivirus to work with Accounts Business in a multi-user environment
Photo of michael.coates

michael.coates

  • 144 Points 100 badge 2x thumb
I really wish it was that easy, you need to do file sharing, folder sharing, user access etc. etc. etc. You can tell how good the instructions are when they refer to Reckon Accounts in one section and then what is now a competitor's product 'Quickbooks' in another section. I will give it a go but I probably won't be a happy camper. I will be surprised if I can get it all to work myself.  Why do you still have reference to what is now a competitor's product, I don't understand that ?
Photo of John G

John G, Information Support Analyst

  • 27,360 Points 20k badge 2x thumb
Hi Michael,

We are not referring to competitor products at all as up to 2013 our product was called QuickBooks, and those versions will always be referred to as QuickBooks.

The KB article, written before 2013, is as relevant to current editions as it is to pre 2013 editions.  

Thanks for highlighting the problem the two names can cause; we have made one line in the KB article a little clearer.


regards,
John.
Photo of Tim Spillman

Tim Spillman

  • 3,212 Points 3k badge 2x thumb
This Script does most of what you want, I wrote this some years ago and have added to it over the years. I recommend that your data file is located in its own folder (not the software installation folder) this helps with not having to share the folder on each installation/upgrade, its is also good file management.

Works from VISTA and above (not sure about home version, should do) supports RA 13 and above.

Copy and place in a text file(notepad not word) save it as a .bat file in your datafile (qbw) location.

Right Click and Run as Administrator.

Feel free to use and abuse it.

::Reckon Accounts Installation - Firewall Exceptions & User Permissions (RA-INSTALLPREP.bat)
::Place RA-INSTALLPREP.bat file in your datafile (QBW) location.
@ECHO OFF
SETLOCAL
CLS
set TITLE=Reckon Accounts Installation
set DATAFOLDER=%~dp0
IF %DATAFOLDER:~-1%==\ SET DATAFOLDER=%DATAFOLDER:~0,-1%
GOTO Start
:Start
ECHO *** %TITLE% ***
ECHO *** Firewall Exceptions and User Permissions ***
ECHO.
ECHO 1.Reckon Accounts 2013
ECHO 2.Reckon Accounts 2014
ECHO 3.Reckon Accounts 2015
ECHO 4.Reckon Accounts 2016
ECHO 5.Reckon Accounts 2017
ECHO.

CHOICE /C 12345 /M "Select a Version:"

IF ERRORLEVEL 5 GOTO 2017
IF ERRORLEVEL 4 GOTO 2016
IF ERRORLEVEL 3 GOTO 2015
IF ERRORLEVEL 2 GOTO 2014
IF ERRORLEVEL 1 GOTO 2013

:2013
set YEAR=2013
set PORT=10176
set FOLDER=ReckonAccounts 2013
set DATAUSER=QBDataServiceUser22
goto CheckOS

:2014
set YEAR=2014
set PORT=10177
set FOLDER=Reckon Accounts 2014
set DATAUSER=QBDataServiceUser23
goto CheckOS

:2015
set YEAR=2015
set PORT=10178
set FOLDER=Reckon Accounts 2015
set DATAUSER=QBDataServiceUser24
goto CheckOS

:2016
set YEAR=2016
set PORT=10179
set FOLDER=Reckon Accounts 2016
set DATAUSER=QBDataServiceUser25
goto CheckOS

:2017
set YEAR=2017
set PORT=10180
set FOLDER=Reckon Accounts 2017
set DATAUSER=QBDataServiceUser26
goto CheckOS

:CheckOS
IF EXIST "%PROGRAMFILES(X86)%" ( GOTO 64Bit ) ELSE ( GOTO 32Bit )

:32Bit
set INSTALL=%PROGRAMFILES%
goto Action

:64Bit
set INSTALL=%PROGRAMFILES(X86)%
goto Action

:Action
ECHO.
ECHO 1.Add %YEAR% Exceptions
ECHO 2.Delete %YEAR% Exceptions
ECHO.

CHOICE /C 12 /M "Select a Action:"

IF ERRORLEVEL 2 GOTO DeleteExceptions
IF ERRORLEVEL 1 GOTO AddExceptions

:AddCommonExceptions
ECHO.
ECHO *** Common Firewall Exceptions ***
ECHO.
ECHO Adding QBCFMonitorService
netsh advfirewall firewall add rule name="Reckon Accounts - QBCFMonitorService" program="%INSTALL%\Common Files\Intuit\QuickBooks\QBCFMonitorService.exe" action=allow program enable=yes dir=in profile=any
ECHO Adding QBUpdate
netsh advfirewall firewall add rule name="Reckon Accounts - QBUpdate" program="%INSTALL%\Common Files\Intuit\QuickBooks\QBUpdate\qbupdate.exe" action=allow program enable=yes dir=in profile=any
GOTO CheckSharing

:AddExceptions
ECHO.
ECHO *** Firewall Exceptions ***
ECHO.
ECHO Adding %YEAR% - Filemangement
netsh advfirewall firewall add rule name="Reckon Accounts %YEAR% - Filemangement" program="%INSTALL%\Intuit\%FOLDER%\FileManagement.exe" action=allow program enable=yes dir=in profile=any
ECHO Adding %YEAR% - QBDBMgr
netsh advfirewall firewall add rule name="Reckon Accounts %YEAR% - QBDBMgr" program="%INSTALL%\Intuit\%FOLDER%\QBDBMgr.exe" action=allow program enable=yes dir=in profile=any
ECHO Adding %YEAR% - QBDBMgrN
netsh advfirewall firewall add rule name="Reckon Accounts %YEAR% - QBDBMgrN" program="%INSTALL%\Intuit\%FOLDER%\QBDBMgrN.exe" action=allow program enable=yes dir=in profile=any
ECHO Adding %YEAR% - QBGDSPlugin
netsh advfirewall firewall add rule name="Reckon Accounts %YEAR% - QBGDSPlugin" program="%INSTALL%\Intuit\%FOLDER%\QBGDSPlugin.exe" action=allow program enable=yes dir=in profile=any
ECHO Adding %YEAR% - QBW32
netsh advfirewall firewall add rule name="Reckon Accounts %YEAR% - QBW32" program="%INSTALL%\Intuit\%FOLDER%\QBW32.exe" action=allow program enable=yes dir=in profile=any
ECHO Adding %YEAR% - Port:%PORT%
netsh advfirewall firewall add rule name="Reckon Accounts %YEAR% - Port" dir=in action=allow protocol=TCP localport=%PORT%
ECHO.
ECHO *** Folder Permissions ***
ECHO.
ECHO Adding Folder Permissions - user:%DATAUSER%
icacls "%DATAFOLDER%" /q /t /grant %DATAUSER%:F
GOTO AddCommonExceptions

:DeleteCommonCheck
ECHO.
ECHO *** WARNING WARNING WARNING ***
ECHO.

CHOICE /C YN /M "You are about to delete common exceptions that may be used by other versions, press N to cancel or Y to continue."

IF ERRORLEVEL 2 GOTO CheckSharing
IF ERRORLEVEL 1 GOTO DeleteCommonExceptions

:DeleteCommonExceptions
ECHO.
ECHO *** Common Firewall Exceptions ***
ECHO.
ECHO Deleting QBCFMonitorService
netsh advfirewall firewall delete rule name="Reckon Accounts - QBCFMonitorService" program="%INSTALL%\Common Files\Intuit\QuickBooks\QBCFMonitorService.exe"
ECHO Deleting QBUpdate
netsh advfirewall firewall delete rule name="Reckon Accounts - QBUpdate" program="%INSTALL%\Common Files\Intuit\QuickBooks\QBUpdate\qbupdate.exe"
GOTO CheckSharing

:DeleteExceptions
ECHO.
ECHO *** Firewall Exceptions ***
ECHO.
ECHO Deleting %YEAR% - Filemangement
netsh advfirewall firewall delete rule name="Reckon Accounts %YEAR% - Filemangement" program="%INSTALL%\Intuit\%FOLDER%\FileManagement.exe"
ECHO Deleting %YEAR% - QBDBMgr
netsh advfirewall firewall delete rule name="Reckon Accounts %YEAR% - QBDBMgr" program="%INSTALL%\Intuit\%FOLDER%\QBDBMgr.exe"
ECHO Deleting %YEAR% - QBDBMgrN
netsh advfirewall firewall delete rule name="Reckon Accounts %YEAR% - QBDBMgrN" program="%INSTALL%\Intuit\%FOLDER%\QBDBMgrN.exe"
ECHO Deleting %YEAR% - QBGDSPlugin
netsh advfirewall firewall delete rule name="Reckon Accounts %YEAR% - QBGDSPlugin" program="%INSTALL%\Intuit\%FOLDER%\QBGDSPlugin.exe"
ECHO Deleting %YEAR% - QBW32
netsh advfirewall firewall delete rule name="Reckon Accounts %YEAR% - QBW32" program="%INSTALL%\Intuit\%FOLDER%\QBW32.exe"
ECHO Deleting %YEAR% - QBW32
netsh advfirewall firewall delete rule name="Reckon Accounts %YEAR% - Port" protocol=TCP localport=%PORT%
ECHO.
ECHO *** Folder Permissions ***
ECHO.
ECHO Deleting Folder Permissions - user:%DATAUSER%
icacls "%DATAFOLDER%" /q /t /remove %DATAUSER%
GOTO DeleteCommonCheck

:AddSharing
ECHO.
ECHO *** Folder Permissions ***
ECHO.
ECHO Adding Folder Permissions - user:everyone
icacls "%DATAFOLDER%" /q /t /grant everyone:m
GOTO Finish

:DeleteSharing
ECHO.
ECHO *** Folder Permissions ***
ECHO.
ECHO Deleting Folder Permissions - user:everyone
icacls "%DATAFOLDER%" /q /t /remove everyone
GOTO Finish

:CheckSharing
ECHO.
ECHO *** MULTIUSER - SIMPLE SHARED FOLDER PERMISSIONS ***
ECHO.
ECHO The User 'EVERYONE' will be granted MODIFY rights to your data folder, NOT recommended in a Enterprise Environment(Active Directory), consult I.T. Support
ECHO.

CHOICE /C YND /M "Change user 'EVERYONE' data folder permissions, press N to cancel, Y to apply or D to Delete."

IF ERRORLEVEL 3 GOTO DeleteSharing
IF ERRORLEVEL 2 GOTO Finish
IF ERRORLEVEL 1 GOTO AddSharing

:Finish
ECHO.
ECHO *** %TITLE% - COMPLETED***
ECHO.

CHOICE /C CE /M "Press E to Exit or C to continue"

IF ERRORLEVEL 2 GOTO EOF
IF ERRORLEVEL 1 GOTO Start
(Edited)
Photo of damask

damask

  • 32 Points
Is it possible to run this on Server 2008 r2 ?
Photo of Tim Spillman

Tim Spillman

  • 3,212 Points 3k badge 2x thumb
Yes, what can be done with the script can also do undone with the script.
Photo of John G

John G, Information Support Analyst

  • 27,360 Points 20k badge 2x thumb
Hello Damask,

thanks for asking, and yes you can install Reckon Accounts on a Server 2008R2.  Please see our guide here.

Hope this helps.


regards,
John
Photo of michael.coates

michael.coates

  • 144 Points 100 badge 2x thumb
WOW.....  

At first I was afraid, I was petrified.....   Sorry that's and 1980s song.

I was afraid to try something which made absolutely no sense to me because I am not a coder but I went through the process as you described and it works a treat ! !  

Tim, thank you so very much for your efforts and more importantly, thank you for sharing the results of your hard work.

I ran your code, answered the simple questions that it asked and presto, both of my computers can now connected to the installation location and everything seems to be working perfectly from my initial assessment. What I can't understand is why can't a company selling software actually do this themselves ?
.
Again, thank you very much Tim !   It is really appreciated !
Photo of Daniel F

Daniel F

  • 180 Points 100 badge 2x thumb
I've updated the file with what I believe to be the details for 2018. Full credit still goes to Tim. I haven't tested it yet, if anyone sees an error, please contribute.

::Reckon Accounts Installation - Firewall Exceptions & User Permissions (RA-INSTALLPREP.bat)
::Place RA-INSTALLPREP.bat file in your datafile (QBW) location.
@ECHO OFF
SETLOCAL
CLS
set TITLE=Reckon Accounts Installation
set DATAFOLDER=%~dp0
IF %DATAFOLDER:~-1%==\ SET DATAFOLDER=%DATAFOLDER:~0,-1%
GOTO Start

:Start
ECHO *** %TITLE% ***
ECHO *** Firewall Exceptions and User Permissions ***
ECHO.
ECHO 1.Reckon Accounts 2013
ECHO 2.Reckon Accounts 2014
ECHO 3.Reckon Accounts 2015
ECHO 4.Reckon Accounts 2016
ECHO 5.Reckon Accounts 2017
ECHO 6.Reckon Accounts 2018
ECHO.

CHOICE /C 123456 /M "Select a Version:"

IF ERRORLEVEL 6 GOTO 2018
IF ERRORLEVEL 5 GOTO 2017
IF ERRORLEVEL 4 GOTO 2016
IF ERRORLEVEL 3 GOTO 2015
IF ERRORLEVEL 2 GOTO 2014
IF ERRORLEVEL 1 GOTO 2013

:2013
set YEAR=2013
set PORT=10176
set FOLDER=ReckonAccounts 2013
set DATAUSER=QBDataServiceUser22
goto CheckOS

:2014
set YEAR=2014
set PORT=10177
set FOLDER=Reckon Accounts 2014
set DATAUSER=QBDataServiceUser23
goto CheckOS

:2015
set YEAR=2015
set PORT=10178
set FOLDER=Reckon Accounts 2015
set DATAUSER=QBDataServiceUser24
goto CheckOS

:2016
set YEAR=2016
set PORT=10179
set FOLDER=Reckon Accounts 2016
set DATAUSER=QBDataServiceUser25
goto CheckOS

:2017
set YEAR=2017
set PORT=10180
set FOLDER=Reckon Accounts 2017
set DATAUSER=QBDataServiceUser26
goto CheckOS

:2018
set YEAR=2018
set PORT=10181
set FOLDER=Reckon Accounts 2018
set DATAUSER=QBDataServiceUser27
GOTO CheckOS

:CheckOS
IF EXIST "%PROGRAMFILES(X86)%" ( GOTO 64Bit ) ELSE ( GOTO 32Bit )

:32Bit
set INSTALL=%PROGRAMFILES%
goto Action

:64Bit
set INSTALL=%PROGRAMFILES(X86)%
goto Action

:Action
ECHO.
ECHO 1.Add %YEAR% Exceptions
ECHO 2.Delete %YEAR% Exceptions
ECHO.
CHOICE /C 12 /M "Select a Action:"
IF ERRORLEVEL 2 GOTO DeleteExceptions
IF ERRORLEVEL 1 GOTO AddExceptions

:AddCommonExceptions
ECHO.
ECHO *** Common Firewall Exceptions ***
ECHO.
ECHO Adding QBCFMonitorService
netsh advfirewall firewall add rule name="Reckon Accounts - QBCFMonitorService" program="%INSTALL%\Common Files\Intuit\QuickBooks\QBCFMonitorService.exe" action=allow program enable=yes dir=in profile=any
ECHO Adding QBUpdate
netsh advfirewall firewall add rule name="Reckon Accounts - QBUpdate" program="%INSTALL%\Common Files\Intuit\QuickBooks\QBUpdate\qbupdate.exe" action=allow program enable=yes dir=in profile=any
GOTO CheckSharing

:AddExceptions
ECHO.
ECHO *** Firewall Exceptions ***
ECHO.
ECHO Adding %YEAR% - Filemangement
netsh advfirewall firewall add rule name="Reckon Accounts %YEAR% - Filemangement" program="%INSTALL%\Intuit\%FOLDER%\FileManagement.exe" action=allow program enable=yes dir=in profile=any
ECHO Adding %YEAR% - QBDBMgr
netsh advfirewall firewall add rule name="Reckon Accounts %YEAR% - QBDBMgr" program="%INSTALL%\Intuit\%FOLDER%\QBDBMgr.exe" action=allow program enable=yes dir=in profile=any
ECHO Adding %YEAR% - QBDBMgrN
netsh advfirewall firewall add rule name="Reckon Accounts %YEAR% - QBDBMgrN" program="%INSTALL%\Intuit\%FOLDER%\QBDBMgrN.exe" action=allow program enable=yes dir=in profile=any
ECHO Adding %YEAR% - QBGDSPlugin
netsh advfirewall firewall add rule name="Reckon Accounts %YEAR% - QBGDSPlugin" program="%INSTALL%\Intuit\%FOLDER%\QBGDSPlugin.exe" action=allow program enable=yes dir=in profile=any
ECHO Adding %YEAR% - QBW32
netsh advfirewall firewall add rule name="Reckon Accounts %YEAR% - QBW32" program="%INSTALL%\Intuit\%FOLDER%\QBW32.exe" action=allow program enable=yes dir=in profile=any
ECHO Adding %YEAR% - Port:%PORT%
netsh advfirewall firewall add rule name="Reckon Accounts %YEAR% - Port" dir=in action=allow protocol=TCP localport=%PORT%
ECHO.
ECHO *** Folder Permissions ***
ECHO.
ECHO Adding Folder Permissions - user:%DATAUSER%
icacls "%DATAFOLDER%" /q /t /grant %DATAUSER%:F
GOTO AddCommonExceptions

:DeleteCommonCheck
ECHO.
ECHO *** WARNING WARNING WARNING ***
ECHO.
CHOICE /C YN /M "You are about to delete common exceptions that may be used by other versions, press N to cancel or Y to continue."
IF ERRORLEVEL 2 GOTO CheckSharing
IF ERRORLEVEL 1 GOTO DeleteCommonExceptions

:DeleteCommonExceptions
ECHO.
ECHO *** Common Firewall Exceptions ***
ECHO.
ECHO Deleting QBCFMonitorService
netsh advfirewall firewall delete rule name="Reckon Accounts - QBCFMonitorService" program="%INSTALL%\Common Files\Intuit\QuickBooks\QBCFMonitorService.exe"
ECHO Deleting QBUpdate
netsh advfirewall firewall delete rule name="Reckon Accounts - QBUpdate" program="%INSTALL%\Common Files\Intuit\QuickBooks\QBUpdate\qbupdate.exe"
GOTO CheckSharing

:DeleteExceptions
ECHO.
ECHO *** Firewall Exceptions ***
ECHO.
ECHO Deleting %YEAR% - Filemangement
netsh advfirewall firewall delete rule name="Reckon Accounts %YEAR% - Filemangement" program="%INSTALL%\Intuit\%FOLDER%\FileManagement.exe"
ECHO Deleting %YEAR% - QBDBMgr
netsh advfirewall firewall delete rule name="Reckon Accounts %YEAR% - QBDBMgr" program="%INSTALL%\Intuit\%FOLDER%\QBDBMgr.exe"
ECHO Deleting %YEAR% - QBDBMgrN
netsh advfirewall firewall delete rule name="Reckon Accounts %YEAR% - QBDBMgrN" program="%INSTALL%\Intuit\%FOLDER%\QBDBMgrN.exe"
ECHO Deleting %YEAR% - QBGDSPlugin
netsh advfirewall firewall delete rule name="Reckon Accounts %YEAR% - QBGDSPlugin" program="%INSTALL%\Intuit\%FOLDER%\QBGDSPlugin.exe"
ECHO Deleting %YEAR% - QBW32
netsh advfirewall firewall delete rule name="Reckon Accounts %YEAR% - QBW32" program="%INSTALL%\Intuit\%FOLDER%\QBW32.exe"
ECHO Deleting %YEAR% - QBW32
netsh advfirewall firewall delete rule name="Reckon Accounts %YEAR% - Port" protocol=TCP localport=%PORT%
ECHO.
ECHO *** Folder Permissions ***
ECHO.
ECHO Deleting Folder Permissions - user:%DATAUSER%
icacls "%DATAFOLDER%" /q /t /remove %DATAUSER%
GOTO DeleteCommonCheck

:AddSharing
ECHO.
ECHO *** Folder Permissions ***
ECHO.
ECHO Adding Folder Permissions - user:reckon_users
icacls "%DATAFOLDER%" /q /t /grant reckon_users:m
GOTO Finish
:DeleteSharing
ECHO.
ECHO *** Folder Permissions ***
ECHO.
ECHO Deleting Folder Permissions - user:reckon_users
icacls "%DATAFOLDER%" /q /t /remove reckon_users
GOTO Finish

:CheckSharing
ECHO.
ECHO *** MULTIUSER - SIMPLE SHARED FOLDER PERMISSIONS ***
ECHO.
ECHO The User 'reckon_users' will be granted MODIFY rights to your data folder, this group will need to be added as a security group in an Enterprise Environment(Active Directory)
ECHO.
CHOICE /C YND /M "Change user 'reckon_users' data folder permissions, press N to cancel, Y to apply or D to Delete."
IF ERRORLEVEL 3 GOTO DeleteSharing
IF ERRORLEVEL 2 GOTO Finish
IF ERRORLEVEL 1 GOTO AddSharing

:Finish
ECHO.
ECHO *** %TITLE% - COMPLETED***
ECHO.
CHOICE /C CE /M "Press E to Exit or C to continue"
IF ERRORLEVEL 2 GOTO EOF
IF ERRORLEVEL 1 GOTO Start
(Edited)
Photo of Tim Spillman

Tim Spillman

  • 3,212 Points 3k badge 2x thumb
usergroup will be an issue, so i have posted a modified script below
(Edited)
Photo of Daniel F

Daniel F

  • 180 Points 100 badge 2x thumb
You're a star Tim, thanks for that. I looked at the usergroup, but not hard enough, obviously. Very nice work
(Edited)
Photo of Tim Spillman

Tim Spillman

  • 3,212 Points 3k badge 2x thumb
Here is my modified script

  • Added Default Usergroup (Can be changed in script and during execution)
  • Added 2018 Support if correct..

::Reckon Accounts Installation - Firewall Exceptions & User Permissions (RA-INSTALLPREP.bat)
::Place RA-INSTALLPREP.bat file in your datafile (QBW) location.
@ECHO OFF
SETLOCAL
CLS
::Usergroup Default Setting (change if required)
:: example(set DEFAULT_USERGROUP=Reckon_Users) will set folder permissions of the 'Reckon_Users' group to modify.
set DEFAULT_USERGROUP=everyone

::DONT NOT CHANGE
set TITLE=Reckon Accounts Installation
set DATAFOLDER=%~dp0
IF %DATAFOLDER:~-1%==\ SET DATAFOLDER=%DATAFOLDER:~0,-1%
GOTO Start
:Start
ECHO *** %TITLE% ***
ECHO *** Firewall Exceptions and Folder Permissions ***
ECHO.
ECHO 1.Reckon Accounts 2013
ECHO 2.Reckon Accounts 2014
ECHO 3.Reckon Accounts 2015
ECHO 4.Reckon Accounts 2016
ECHO 5.Reckon Accounts 2017
ECHO 6.Reckon Accounts 2018
ECHO. 

CHOICE /C 123456 /M "Select a Version:"

IF ERRORLEVEL 6 GOTO 2018
IF ERRORLEVEL 5 GOTO 2017
IF ERRORLEVEL 4 GOTO 2016
IF ERRORLEVEL 3 GOTO 2015
IF ERRORLEVEL 2 GOTO 2014
IF ERRORLEVEL 1 GOTO 2013

:2013
set YEAR=2013
set PORT=10176
set FOLDER=ReckonAccounts 2013
set DATAUSER=QBDataServiceUser22
goto CheckOS

:2014
set YEAR=2014
set PORT=10177
set FOLDER=Reckon Accounts 2014
set DATAUSER=QBDataServiceUser23
goto CheckOS

:2015
set YEAR=2015
set PORT=10178
set FOLDER=Reckon Accounts 2015
set DATAUSER=QBDataServiceUser24
goto CheckOS

:2016
set YEAR=2016
set PORT=10179
set FOLDER=Reckon Accounts 2016
set DATAUSER=QBDataServiceUser25
goto CheckOS

:2017
set YEAR=2017
set PORT=10180
set FOLDER=Reckon Accounts 2017
set DATAUSER=QBDataServiceUser26
goto CheckOS

:2018
set YEAR=2018
set PORT=10181
set FOLDER=Reckon Accounts 2018
set DATAUSER=QBDataServiceUser27
goto CheckOS

:CheckOS
IF EXIST "%PROGRAMFILES(X86)%" ( GOTO 64Bit ) ELSE ( GOTO 32Bit )

:32Bit
set INSTALL=%PROGRAMFILES%
goto Action

:64Bit
set INSTALL=%PROGRAMFILES(X86)%
goto Action

:Action
ECHO.
ECHO 1.Add %YEAR% Exceptions
ECHO 2.Delete %YEAR% Exceptions
ECHO.

CHOICE /C 12 /M "Select a Action:"

IF ERRORLEVEL 2 GOTO DeleteExceptions
IF ERRORLEVEL 1 GOTO AddExceptions

:AddCommonExceptions
ECHO.
ECHO *** Common Firewall Exceptions ***
ECHO.
ECHO Adding QBCFMonitorService 
netsh advfirewall firewall add rule name="Reckon Accounts - QBCFMonitorService" program="%INSTALL%\Common Files\Intuit\QuickBooks\QBCFMonitorService.exe" action=allow program enable=yes dir=in profile=any
ECHO Adding QBUpdate
netsh advfirewall firewall add rule name="Reckon Accounts - QBUpdate" program="%INSTALL%\Common Files\Intuit\QuickBooks\QBUpdate\qbupdate.exe" action=allow program enable=yes dir=in profile=any
GOTO CheckUserGroup

:AddExceptions
ECHO.
ECHO *** Firewall Exceptions ***
ECHO.
ECHO Adding %YEAR% - Filemangement
netsh advfirewall firewall add rule name="Reckon Accounts %YEAR% - Filemangement" program="%INSTALL%\Intuit\%FOLDER%\FileManagement.exe" action=allow program enable=yes dir=in profile=any
ECHO Adding %YEAR% - QBDBMgr
netsh advfirewall firewall add rule name="Reckon Accounts %YEAR% - QBDBMgr" program="%INSTALL%\Intuit\%FOLDER%\QBDBMgr.exe" action=allow program enable=yes dir=in profile=any
ECHO Adding %YEAR% - QBDBMgrN
netsh advfirewall firewall add rule name="Reckon Accounts %YEAR% - QBDBMgrN" program="%INSTALL%\Intuit\%FOLDER%\QBDBMgrN.exe" action=allow program enable=yes dir=in profile=any
ECHO Adding %YEAR% - QBGDSPlugin
netsh advfirewall firewall add rule name="Reckon Accounts %YEAR% - QBGDSPlugin" program="%INSTALL%\Intuit\%FOLDER%\QBGDSPlugin.exe" action=allow program enable=yes dir=in profile=any
ECHO Adding %YEAR% - QBW32
netsh advfirewall firewall add rule name="Reckon Accounts %YEAR% - QBW32" program="%INSTALL%\Intuit\%FOLDER%\QBW32.exe" action=allow program enable=yes dir=in profile=any
ECHO Adding %YEAR% - Port:%PORT%
netsh advfirewall firewall add rule name="Reckon Accounts %YEAR% - Port" dir=in action=allow protocol=TCP localport=%PORT%
ECHO.
ECHO *** Folder Permissions ***
ECHO.
ECHO Adding Folder Permissions - user:%DATAUSER%
icacls "%DATAFOLDER%" /q /t /grant %DATAUSER%:F
GOTO AddCommonExceptions

:DeleteCommonCheck
ECHO.
ECHO *** WARNING WARNING WARNING ***
ECHO.

CHOICE /C YN /M "You are about to delete common exceptions that may be used by other versions, press N to cancel or Y to continue."

IF ERRORLEVEL 2 GOTO CheckUserGroup
IF ERRORLEVEL 1 GOTO DeleteCommonExceptions

:DeleteCommonExceptions
ECHO.
ECHO *** Common Firewall Exceptions ***
ECHO.
ECHO Deleting QBCFMonitorService
netsh advfirewall firewall delete rule name="Reckon Accounts - QBCFMonitorService" program="%INSTALL%\Common Files\Intuit\QuickBooks\QBCFMonitorService.exe"
ECHO Deleting QBUpdate
netsh advfirewall firewall delete rule name="Reckon Accounts - QBUpdate" program="%INSTALL%\Common Files\Intuit\QuickBooks\QBUpdate\qbupdate.exe"
GOTO CheckSharing

:DeleteExceptions
ECHO.
ECHO *** Firewall Exceptions ***
ECHO.
ECHO Deleting %YEAR% - Filemangement
netsh advfirewall firewall delete rule name="Reckon Accounts %YEAR% - Filemangement" program="%INSTALL%\Intuit\%FOLDER%\FileManagement.exe"
ECHO Deleting %YEAR% - QBDBMgr
netsh advfirewall firewall delete rule name="Reckon Accounts %YEAR% - QBDBMgr" program="%INSTALL%\Intuit\%FOLDER%\QBDBMgr.exe"
ECHO Deleting %YEAR% - QBDBMgrN
netsh advfirewall firewall delete rule name="Reckon Accounts %YEAR% - QBDBMgrN" program="%INSTALL%\Intuit\%FOLDER%\QBDBMgrN.exe"
ECHO Deleting %YEAR% - QBGDSPlugin
netsh advfirewall firewall delete rule name="Reckon Accounts %YEAR% - QBGDSPlugin" program="%INSTALL%\Intuit\%FOLDER%\QBGDSPlugin.exe"
ECHO Deleting %YEAR% - QBW32
netsh advfirewall firewall delete rule name="Reckon Accounts %YEAR% - QBW32" program="%INSTALL%\Intuit\%FOLDER%\QBW32.exe"
ECHO Deleting %YEAR% - QBW32
netsh advfirewall firewall delete rule name="Reckon Accounts %YEAR% - Port" protocol=TCP localport=%PORT% 
ECHO.
ECHO *** Folder Permissions ***
ECHO.
ECHO Deleting Folder Permissions - user:%DATAUSER%
icacls "%DATAFOLDER%" /q /t /remove %DATAUSER%
GOTO DeleteCommonCheck

:ChangeUserGroup
ECHO.
set /p USERGROUP="Please enter the User Group and press enter:"
ECHO.
ECHO User Group has been set to '%USERGROUP%'
ECHO.
CHOICE /C YNC /M "Is this correct? Y to continue, N to change, C to Cancel"

IF ERRORLEVEL 3 GOTO CheckUserGroup
IF ERRORLEVEL 2 GOTO ChangeUserGroup
IF ERRORLEVEL 1 GOTO CheckSharing

:CheckUserGroup
set USERGROUP=%DEFAULT_USERGROUP%
ECHO.
ECHO *** USERGROUP PERMISSIONS ***
ECHO.
ECHO The current default UserGroup '%USERGROUP%' will be used to grant rights to your data folder, using 'everyone' is NOT recommended in a Enterprise Environment(Active Directory), consult I.T. Support
ECHO.
CHOICE /C YN /M "Do you wish to change the default usergroup? (Default:%USERGROUP%) press Y to change, N to continue."

IF ERRORLEVEL 2 GOTO CheckSharing
IF ERRORLEVEL 1 GOTO ChangeUserGroup

:AddSharing
ECHO.
ECHO *** Folder Permissions ***
ECHO.
ECHO Adding Folder Permissions - user:%USERGROUP%
icacls "%DATAFOLDER%" /q /t /grant %USERGROUP%:m
GOTO Finish

:DeleteSharing
ECHO.
ECHO *** Folder Permissions ***
ECHO.
ECHO Deleting Folder Permissions - user:%USERGROUP%
icacls "%DATAFOLDER%" /q /t /remove %USERGROUP%
GOTO Finish

:CheckSharing
ECHO.
ECHO *** MULTIUSER - SHARED FOLDER PERMISSIONS ***
ECHO.
ECHO The User '%USERGROUP%' will be granted MODIFY rights to your data folder.
ECHO.

CHOICE /C YND /M "Change user '%USERGROUP%' data folder permissions, press N to cancel, Y to apply or D to Delete."

IF ERRORLEVEL 3 GOTO DeleteSharing
IF ERRORLEVEL 2 GOTO Finish
IF ERRORLEVEL 1 GOTO AddSharing

:Finish
ECHO.
ECHO *** %TITLE% - COMPLETED***
ECHO.

CHOICE /C CE /M "Press E to Exit or C to continue"

IF ERRORLEVEL 2 GOTO EOF
IF ERRORLEVEL 1 GOTO Start

(Edited)
Photo of Rodney Freed

Rodney Freed

  • 62 Points
THANK YOU, THANK YOU, THANK YOU!!! I had the same problem after upgrading, looked on internet and found the latest 2018 version of the script. With heart in mouth, I ran it, and HEY PRESTO, it all works. Now did I say thank you before!!!
Photo of Shane Harris

Shane Harris

  • 160 Points 100 badge 2x thumb
Hi Everyone,
I have modified this script to allow for the the multiple ports listed here:
  • QuickBooks Desktop 2018: 8019, 56728, 55378-55382
  • QuickBooks Desktop 2017: 8019, 56727, 55373-55377
  • QuickBooks Desktop 2016: 8019, 56726, 55368-55372
File needs to be ran as Administrator, after running the script, you need to restart your computer.

Get the file here: http://bit.ly/QB-Script

Cheers
Photo of Shane Harris

Shane Harris

  • 160 Points 100 badge 2x thumb
Very strange, the single port didn’t work for me, I had to add the multiple ports I found mentioned on google for it to work. Either way, thanks heaps for your original script, it helped me a few times.
Photo of Daniel F

Daniel F

  • 180 Points 100 badge 2x thumb
" it helped me a few times" - a slight understatement :)
Photo of Shane Harris

Shane Harris

  • 160 Points 100 badge 2x thumb
hahaha perhaps I should have said "I have needed it every time I have upgraded"
Photo of Daniel F

Daniel F

  • 180 Points 100 badge 2x thumb
Ha ha, me too. Original script is by  Tim Spillman, by the way, not me. Think about editting  Quickbooks_Port_Fix/#L245
Photo of Danielle Carlson

Danielle Carlson

  • 106 Points 100 badge 2x thumb
Does anyone have the script for Quickbooks 2011/12 by any chance?
Photo of Tim Spillman

Tim Spillman

  • 3,212 Points 3k badge 2x thumb
Support from Windows VIsta,Windows Server 2008 & Above

Quickbooks 08 - 12/13 
QB - INSTALLPREP.TXT
Reckon Accounts 13 - Current
RA - INSTALLPREP.TXT
(Edited)